code source :

import com.mutationevent.TypeWriter;
var tw:TypeWriter = new TypeWriter(theText, 1, 10);
tw.addEventListener(TypeWriter.COMPLETE, onComplete);
function onComplete(event:Event)
{
	trace("complete", event);
}

class :

/*
* Copyright 2009 Achraf bouyakhsass [http://www.mutationevent.com]
*
* Licensed under the Apache License, Version 2.0 (the "License");
* you may not use this file except in compliance with the License.
* You may obtain a copy of the License at
*
*     http://www.apache.org/licenses/LICENSE-2.0
*
* Unless required by applicable law or agreed to in writing, software
* distributed under the License is distributed on an "AS IS" BASIS,
* WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied.
* See the License for the specific language governing permissions and
* limitations under the License.
*/
package com.mutationevent
{
	import flash.events.*;
	import flash.utils.Timer;
	import flash.text.TextField;
 
	public class TypeWriter extends EventDispatcher
	{
		private var timer:Timer;
		private var count:Number = 0;
		private var str:String;
		private var target:TextField;
		private var charJump:Number = 1;
		private var speed:Number = 50;
		public static var COMPLETE:String = "complete";
 
		public function TypeWriter(tf:TextField, cj:Number, sp:Number)
		{
			charJump = cj;
			speed = sp;
			target = tf;
			str = target.text;
			target.text = "";
 
			timer = new Timer(speed);
			timer.addEventListener(TimerEvent.TIMER, write);
			timer.start();
		}
		private function write(event:TimerEvent):void
		{
			target.text = str.substring(0, count);
			count += charJump;
			if(count > str.length)
			{
				timer.removeEventListener(TimerEvent.TIMER, write);
				dispatchEvent(new Event(TypeWriter.COMPLETE));
			}
		}
	}
}

Télécharger le fichier ici : as3 TypeWriter (88)

Réaliser un compte a rebours facilement avec as3.

Nous aurons besoin un champ de texte pour afficher la date, un timer et la classe CountDown de Kazuma Ieiri.

code as 3

import flash.utils.Timer;
import flash.events.TimerEvent;
import jp.hbkr.baka.CountDown;
 
var timer:Timer = new Timer(1000);
var a:Array;
 
timer.addEventListener(TimerEvent.TIMER, tick);
timer.start();
 
function tick(event:TimerEvent):void
{
a = CountDown.getCountDown(2010, 1, 1, 12, 0, 0);
timerContentTXT.text = a[0]+" Jours "+a[1]+" H " + a[2] + " mn et " + a[3]+"s";
}

Télécharger la source ici CountDown (119)

• Tweener
  http://code.google.com/p/tweener/
• TweenLite
  http://blog.greensock.com/tweenliteas3/
• TweenMax
  http://blog.greensock.com/tweenmaxas3/
• GoASAP (ActionScript Animation Platform)
  http://www.goasap.org/
• AS3 Animation System 2.0
  http://www.boostworthy.com/blog/?p=170
• Animation Package
  http://www.alex-uhlmann.de/flash/animationpackage/
• KitchenSync
  http://code.google.com/p/kitchensynclib/
• Gyro - A tween and animation library for ActionScript 3
  http://code.google.com/p/gyro-actionscript-animation/
• gTween
  http://www.gskinner.com/blog/archives/2008/08/gtween_a_new_tw.html
• HydroTween + HydroSequence (based on GoASAP)
  http://blog.hydrotik.com/2008/07/19/hydrotween-hydrosequence-rev32/

Imaginez que vous êtes en train de développer une application pour lire des fichiers au format .flv, .txt ou votre propre format et vous voudriez qu'à chaque fois que l'utilisateur double clique sur le fichier votre application créée avec Adobe Air se lance automatiquement. vous n'aurez qu'a utiliser se code

NativeApplication.nativeApplication.setAsDefaultApplication("flv");

pour faire mieux encore, vous pouvez vérifier si votre application est l'application par défaut de ce type

NativeApplication.nativeApplication.isSetAsDefaultApplication("flv");

si ce n'est pas le cas, vérifier l'application par défaut de ce type de fichier

NativeApplication.nativeApplication.getDefaultApplication("flv");

cela renvoi le chemin vers l'application lier a ce format de fichier. Et pour faire en sorte que votre application ne soit plus lier a ce format de fichier :

NativeApplication.nativeApplication.removeAsDefaultApplication("flv");

Nous savons que pour télécharger un fichier depuis un site avec la machine du client il suffit parfois de le compresser en .zip par exemple et l'ouvrir comme n'importe quel lien et c'est le navigteur qui ouvre la fenêtre de téléchargement puisqu'il n'arrive pas reconnaître ou interpréter le fichier. Mais parfois on a besoin de forcer le téléchargement de certains fichiers cela est possible avec les langages des programmations côté serveur tel que PHP, ASP, JSP, RoR, CFM ...

Cela est désormais possible avec ActionSscript 3, pour cela on besoin de la class FileReference qui se trouve dans le package flash.net.FileReference et qui permet de télécharger n'importe quel fichier grâce à la méthode download.

Supposons que nous voulons télécharger un fichier .zip depuis une URL (http://www.votreserveur.com/fichier.zip)

on peut aussi ajouter des écouteurs d'événement pour savoir si le fichier est en cours de téléchargement, s'il y a eu une erreur, si le téléchargement est terminé et même aussi d'arrêter le téléchargement.

Event.CANCEL
Event.COMPLETE
Event.OPEN
Event.SELECT
HTTPStatusEvent.HTTP_STATUS
IOErrorEvent.IO_ERROR
ProgressEvent.PROGRESS
SecurityErrorEvent.SECURITY_ERROR
DataEvent.UPLOAD_COMPLETE_DATA

code:

package
{
    import flash.display.MovieClip;
    import flash.net.FileReference;
    import flash.net.URLRequest;
    import flash.events.Event;
    import flash.events.ProgressEvent;
    import flash.events.IOErrorEvent;
 
    public class Main extends MovieClip
    {
 
        // Constants:
        // Public Properties:
        public var fileDownload:FileReference;
        public var url:URLRequest;
 
        // Private Properties:
 
        // Initialization:
        public function Main() {
 
            trace("main class loaded");
 
            fileDownload = new FileReference();
            url = new URLRequest("http://www.votreserveur.com/fichier.zip");
 
            fileDownload.addEventListener(ProgressEvent.PROGRESS, onProgress);
            fileDownload.addEventListener(Event.COMPLETE, onComplete);
            fileDownload.addEventListener(IOErrorEvent.IO_ERROR, onError);
 
            fileDownload.download(url);
 
        }
 
        // Public Methods:
        public function onProgress(event:ProgressEvent):void
        {
            trace("chargement en cours : " + event.bytesLoaded / event.bytesTotal);
        }
 
        public function onComplete(event:Event):void
        {
            trace("téléchargement terminer");
        }
 
        public function onError(event:IOErrorEvent):void
        {
            trace("Erreur de chargement du fichier");
        }
 
        // Protected Methods:
    }
 
}

Télécharger le fichier Download File as3 (479)